gl_builtin_shaders.cpp

Go to the documentation of this file.

/*
* This program source code file is part of KICAD, a free EDA CAD application.
*
* Copyright (C) 2016 Kicad Developers, see change_log.txt for contributors.
*
* This program is free software; you can redistribute it and/or
* modify it under the terms of the GNU General Public License
* as published by the Free Software Foundation; either version 2
* of the License, or (at your option) any later version.
*
* This program is distributed in the hope that it will be useful,
* but WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
* GNU General Public License for more details.
*
* You should have received a copy of the GNU General Public License
* along with this program; if not, you may find one here:
* http://www.gnu.org/licenses/old-licenses/gpl-2.0.html
* or you may search the http://www.gnu.org website for the version 2 license,
* or you may write to the Free Software Foundation, Inc.,
* 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301, USA
*/

#include "gl_builtin_shaders.h"

namespace KIGFX {
namespace BUILTIN_SHADERS {

/*
 *
 * KiCad shaders
 *
 */

const char kicad_vertex_shader[] = R"SHADER_SOURCE(

/*
 * This program source code file is part of KICAD, a free EDA CAD application.
 *
 * Copyright (C) 2013-2016 CERN
 * @author Maciej Suminski <[email protected]>
 *
 * Vertex shader
 *
 * This program is free software; you can redistribute it and/or
 * modify it under the terms of the GNU General Public License
 * as published by the Free Software Foundation; either version 2
 * of the License, or (at your option) any later version.
 *
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with this program; if not, you may find one here:
 * http://www.gnu.org/licenses/old-licenses/gpl-2.0.html
 * or you may search the http://www.gnu.org website for the version 2 license,
 * or you may write to the Free Software Foundation, Inc.,
 * 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301, USA
 */

#version 120

// Shader types
const float SHADER_FILLED_CIRCLE = 2.0;
const float SHADER_STROKED_CIRCLE = 3.0;
const float SHADER_FONT = 4.0;
const float SHADER_LINE_A = 5.0;
const float SHADER_LINE_B = 6.0;
const float SHADER_LINE_C = 7.0;
const float SHADER_LINE_D = 8.0;
const float SHADER_LINE_E = 9.0;
const float SHADER_LINE_F = 10.0;

// Minimum line width
const float MIN_WIDTH = 1.0;

attribute vec4 attrShaderParams;
varying vec4 shaderParams;
varying vec2 circleCoords;
uniform float worldPixelSize;
uniform vec2 screenPixelSize;
uniform float pixelSizeMultiplier;
uniform float minLinePixelWidth;
uniform vec2 antialiasingOffset;


float roundr( float f, float r )
{
 return floor(f / r + 0.5) * r;
}

vec4 roundv( vec4 x, vec2 t)
{
 return vec4( roundr(x.x, t.x), roundr(x.y, t.y), x.z, x.w );
}

void computeLineCoords( bool posture, vec2 vs, vec2 vp, vec2 texcoord, vec2 dir, float lineWidth, bool endV )
{
 float lineLength = length(vs);
 vec4 screenPos = gl_ModelViewProjectionMatrix * gl_Vertex + vec4(1, 1, 0, 0);
 float w = ((lineWidth == 0.0) ? worldPixelSize : lineWidth );
 float pixelWidth = roundr( w / worldPixelSize, 1.0 );
 float aspect = ( lineLength + w ) / w;
 vec4 color = gl_Color;
 vec2 s = sign( vec2( gl_ModelViewProjectionMatrix[0][0], gl_ModelViewProjectionMatrix[1][1] ) );


 if( pixelWidth < 1.0 )
 pixelWidth = 1.0;

 if ( pixelWidth > 1.0 || pixelSizeMultiplier > 1.0 )
 {
 vec2 offsetNorm = (vs + vp) * pixelWidth / lineLength * 0.5;
 vec4 screenOffset = vec4( s.x * offsetNorm.x * screenPixelSize.x, s.y * offsetNorm.y * screenPixelSize.y , 0, 0);
 vec4 adjust = vec4(-1, -1, 0, 0);

 if( mod( pixelWidth * pixelSizeMultiplier, 2.0 ) > 0.9 )
 {
 adjust += vec4( screenPixelSize.x, screenPixelSize.y, 0, 0 ) * 0.5;
 }

 gl_Position = roundv(screenPos, screenPixelSize) + adjust + screenOffset;

 shaderParams[0] = SHADER_LINE_A;
 }
 else {
 vec4 pos0 = screenPos;
 pos0.xy += ( posture ? dir.xy : dir.yx ) * screenPixelSize / 2.0;

 if(posture)
 {
 pos0.y -= screenPixelSize.y * sign(vs.y) * 0.5;
 }
 else
 {
 pos0.x += screenPixelSize.x * sign(vs.x) * 0.5;
 }

 gl_Position = pos0 - vec4(1, 1, 0, 0);
 shaderParams[0] = SHADER_LINE_B;
 }

 shaderParams[1] = aspect;

 gl_TexCoord[0].st = vec2(aspect * texcoord.x, texcoord.y);
 gl_FrontColor = gl_Color;
}


void computeCircleCoords( float mode, float vertexIndex, float radius, float lineWidth )
{
 vec4 delta;
 vec4 center = roundv( gl_ModelViewProjectionMatrix * gl_Vertex + vec4(1, 1, 0, 0), screenPixelSize );
 float pixelWidth = roundr( lineWidth / worldPixelSize, 1.0);
 float pixelR = roundr( radius / worldPixelSize, 1.0);

 if( mode == SHADER_STROKED_CIRCLE)
 pixelR += pixelWidth / 2.0;

 vec4 adjust = vec4(-1, -1, 0, 0);

 if( pixelWidth < 1.0 )
 pixelWidth = 1.0;

 if( vertexIndex == 1.0 )
 {
 circleCoords = vec2( -sqrt( 3.0 ), -1.0 );
 delta = vec4( -pixelR * sqrt(3.0), -pixelR, 0, 0 );
 }
 else if( vertexIndex == 2.0 )
 {
 circleCoords = vec2( sqrt( 3.0 ), -1.0 );
 delta = vec4( pixelR * sqrt( 3.0 ), -pixelR, 0, 0 );
 }
 else if( vertexIndex == 3.0 )
 {
 circleCoords = vec2( 0.0, 2.0 );
 delta = vec4( 0, 2 * pixelR, 0, 0 );
 }
 else if( vertexIndex == 4.0 )
 {
 circleCoords = vec2( -sqrt( 3.0 ), 0.0 );
 delta = vec4( 0, 0, 0, 0 );
 }
 else if( vertexIndex == 5.0 )
 {
 circleCoords = vec2( sqrt( 3.0 ), 0.0 );
 delta = vec4( 0, 0, 0, 0 );
 }
 else if( vertexIndex == 6.0 )
 {
 circleCoords = vec2( 0.0, 2.0 );
 delta = vec4( 0, 0, 0, 0 );
 }

 shaderParams[2] = pixelR;
 shaderParams[3] = pixelWidth;

 delta.x *= screenPixelSize.x;
 delta.y *= screenPixelSize.y;

 gl_Position = center + delta + adjust;
 gl_FrontColor = gl_Color;
}


void main()
{
 float mode = attrShaderParams[0];

 // Pass attributes to the fragment shader
 shaderParams = attrShaderParams;

 float lineWidth = shaderParams.y;
 vec2 vs = shaderParams.zw;
 vec2 vp = vec2(-vs.y, vs.x);
 bool posture = abs( vs.x ) < abs(vs.y);

 if( mode == SHADER_LINE_A )
 computeLineCoords( posture, -vs, vp, vec2( -1, -1 ), vec2( -1, 0 ), lineWidth, false );
 else if( mode == SHADER_LINE_B )
 computeLineCoords( posture, -vs, -vp, vec2( -1, 1 ), vec2( 1, 0 ), lineWidth, false );
 else if( mode == SHADER_LINE_C )
 computeLineCoords( posture, vs, -vp, vec2( 1, 1 ), vec2( 1, 0 ), lineWidth, true );
 else if( mode == SHADER_LINE_D )
 computeLineCoords( posture, vs, -vp, vec2( -1, -1 ), vec2( 1, 0 ), lineWidth, true );
 else if( mode == SHADER_LINE_E )
 computeLineCoords( posture, vs, vp, vec2( -1, 1 ), vec2( -1, 0 ), lineWidth, true );
 else if( mode == SHADER_LINE_F )
 computeLineCoords( posture, -vs, vp, vec2( 1, 1 ), vec2( -1, 0 ), lineWidth, false );
 else if( mode == SHADER_FILLED_CIRCLE || mode == SHADER_STROKED_CIRCLE)
 computeCircleCoords( mode, shaderParams.y, shaderParams.z, shaderParams.w );
 else
 {
 // Pass through the coordinates like in the fixed pipeline
 gl_Position = ftransform();
 gl_FrontColor = gl_Color;

 }

 gl_Position.xy += antialiasingOffset;
}

)SHADER_SOURCE";

const char kicad_fragment_shader[] = R"SHADER_SOURCE(

/*
 * This program source code file is part of KICAD, a free EDA CAD application.
 *
 * Copyright (C) 2013-2016 CERN
 * Copyright (C) 2016 Kicad Developers, see authors.txt for contributors.
 * @author Maciej Suminski <[email protected]>
 *
 * Fragment shader
 *
 * This program is free software; you can redistribute it and/or
 * modify it under the terms of the GNU General Public License
 * as published by the Free Software Foundation; either version 2
 * of the License, or (at your option) any later version.
 *
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with this program; if not, you may find one here:
 * http://www.gnu.org/licenses/old-licenses/gpl-2.0.html
 * or you may search the http://www.gnu.org website for the version 2 license,
 * or you may write to the Free Software Foundation, Inc.,
 * 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301, USA
 */

#version 120

// Multi-channel signed distance field
#define USE_MSDF

// Shader types
const float SHADER_FILLED_CIRCLE = 2.0;
const float SHADER_STROKED_CIRCLE = 3.0;
const float SHADER_FONT = 4.0;
const float SHADER_LINE_A = 5.0;

varying vec4 shaderParams;
varying vec2 circleCoords;
uniform sampler2D fontTexture;
uniform float worldPixelSize;

// Needed to reconstruct the mipmap level / texel derivative
uniform int fontTextureWidth;

void filledCircle( vec2 aCoord )
{
 if( dot( aCoord, aCoord ) < 1.0 )
 gl_FragColor = gl_Color;
 else
 discard;
}

float pixelSegDistance( vec2 aCoord )
{
 float aspect = shaderParams[1];
 float dist;
 vec2 v = vec2( 1.0 - ( aspect - abs( aCoord.s ) ), aCoord.t );

 if( v.x <= 0.0 )
 {
 dist = abs( aCoord.t );
 }
 else
 {
 dist = length( v );
 }

 return dist;
}

int isPixelInSegment( vec2 aCoord )
{
 return pixelSegDistance( aCoord ) <= 1.0 ? 1 : 0;
}



void strokedCircle( vec2 aCoord, float aRadius, float aWidth )
{
 float outerRadius = max( aRadius, 0.0 );
 float innerRadius = max( aRadius - aWidth, 0.0 );

 if( ( dot( aCoord, aCoord ) < 1.0 ) &&
 ( dot( aCoord, aCoord ) * ( outerRadius * outerRadius ) > innerRadius * innerRadius ) )
 gl_FragColor = gl_Color;
 else
 discard;
}


void drawLine( vec2 aCoord )
{
 if( isPixelInSegment( aCoord ) != 0)
 gl_FragColor = gl_Color;
 else
 discard;
}

#ifdef USE_MSDF
float median( vec3 v )
{
 return max( min( v.r, v.g ), min( max( v.r, v.g ), v.b ) );
}
#endif

void main()
{
 // VS to FS pipeline does math that means we can't rely on the mode
 // parameter being bit-exact without rounding it first.
 float mode = floor( shaderParams[0] + 0.5 );

 if( mode == SHADER_LINE_A )
 {
 drawLine( gl_TexCoord[0].st );
 }
 else if( mode == SHADER_FILLED_CIRCLE )
 {
 filledCircle( circleCoords );
 }
 else if( mode == SHADER_STROKED_CIRCLE )
 {
 strokedCircle( circleCoords, shaderParams[2], shaderParams[3] );
 }
 else if( mode == SHADER_FONT )
 {
 vec2 tex = shaderParams.yz;

 // Unless we're stretching chars it is okay to consider
 // one derivative for filtering
 float derivative = length( dFdx( tex ) ) * fontTextureWidth / 4;

#ifdef USE_MSDF
 float dist = median( texture2D( fontTexture, tex ).rgb );
#else
 float dist = texture2D( fontTexture, tex ).r;
#endif

 // use the derivative for zoom-adaptive filtering
 float alpha = smoothstep( 0.5 - derivative, 0.5 + derivative, dist ) * gl_Color.a;

 gl_FragColor = vec4( gl_Color.rgb, alpha );
 }
 else
 {
 // Simple pass-through
 gl_FragColor = gl_Color;
 }
}

)SHADER_SOURCE";

const char ssaa_x4_vertex_shader[] = R"SHADER_SOURCE(

#version 120
varying vec2 texcoord;
void main()
{
 texcoord = gl_MultiTexCoord0.st;
 gl_Position = ftransform();
}

)SHADER_SOURCE";

const char ssaa_x4_fragment_shader[] = R"SHADER_SOURCE(

#version 120
varying vec2 texcoord;
uniform sampler2D source;
void main()
{
 float step_x = dFdx(texcoord.x)/4.;
 float step_y = dFdy(texcoord.y)/4.;

 vec4 q00 = texture2D( source, texcoord + vec2(-step_x, -step_y) );
 vec4 q01 = texture2D( source, texcoord + vec2( step_x, -step_y) );
 vec4 q10 = texture2D( source, texcoord + vec2(-step_x, step_y) );
 vec4 q11 = texture2D( source, texcoord + vec2( step_x, step_y) );

 gl_FragColor = (q00+q01+q10+q11)/4;
}

)SHADER_SOURCE";

const char smaa_base_shader_p1[] = R"SHADER_SOURCE(

//-----------------------------------------------------------------------------
// SMAA Presets

#if defined(SMAA_PRESET_LOW)
#define SMAA_THRESHOLD 0.15
#define SMAA_MAX_SEARCH_STEPS 4
#define SMAA_DISABLE_DIAG_DETECTION
#define SMAA_DISABLE_CORNER_DETECTION
#elif defined(SMAA_PRESET_MEDIUM)
#define SMAA_THRESHOLD 0.1
#define SMAA_MAX_SEARCH_STEPS 8
#define SMAA_DISABLE_DIAG_DETECTION
#define SMAA_DISABLE_CORNER_DETECTION
#elif defined(SMAA_PRESET_HIGH)
#define SMAA_THRESHOLD 0.1
#define SMAA_MAX_SEARCH_STEPS 16
#define SMAA_MAX_SEARCH_STEPS_DIAG 8
#define SMAA_CORNER_ROUNDING 25
#elif defined(SMAA_PRESET_ULTRA)
#define SMAA_THRESHOLD 0.05
#define SMAA_MAX_SEARCH_STEPS 32
#define SMAA_MAX_SEARCH_STEPS_DIAG 16
#define SMAA_CORNER_ROUNDING 25
#endif

//-----------------------------------------------------------------------------
// Configurable Defines

#ifndef SMAA_THRESHOLD
#define SMAA_THRESHOLD 0.1
#endif

#ifndef SMAA_DEPTH_THRESHOLD
#define SMAA_DEPTH_THRESHOLD (0.1 * SMAA_THRESHOLD)
#endif

#ifndef SMAA_MAX_SEARCH_STEPS
#define SMAA_MAX_SEARCH_STEPS 16
#endif
)SHADER_SOURCE";

const char smaa_base_shader_p2[] = R"SHADER_SOURCE(
#ifndef SMAA_MAX_SEARCH_STEPS_DIAG
#define SMAA_MAX_SEARCH_STEPS_DIAG 8
#endif

#ifndef SMAA_CORNER_ROUNDING
#define SMAA_CORNER_ROUNDING 25
#endif

#ifndef SMAA_LOCAL_CONTRAST_ADAPTATION_FACTOR
#define SMAA_LOCAL_CONTRAST_ADAPTATION_FACTOR 2.0
#endif

#ifndef SMAA_PREDICATION
#define SMAA_PREDICATION 0
#endif

#ifndef SMAA_PREDICATION_THRESHOLD
#define SMAA_PREDICATION_THRESHOLD 0.01
#endif

#ifndef SMAA_PREDICATION_SCALE
#define SMAA_PREDICATION_SCALE 2.0
#endif

#ifndef SMAA_PREDICATION_STRENGTH
#define SMAA_PREDICATION_STRENGTH 0.4
#endif

#ifndef SMAA_REPROJECTION
#define SMAA_REPROJECTION 0
#endif

#ifndef SMAA_REPROJECTION_WEIGHT_SCALE
#define SMAA_REPROJECTION_WEIGHT_SCALE 30.0
#endif

#ifndef SMAA_INCLUDE_VS
#define SMAA_INCLUDE_VS 1
#endif
#ifndef SMAA_INCLUDE_PS
#define SMAA_INCLUDE_PS 1
#endif

//-----------------------------------------------------------------------------
// Texture Access Defines

#ifndef SMAA_AREATEX_SELECT
#if defined(SMAA_HLSL_3)
#define SMAA_AREATEX_SELECT(sample) sample.ra
#else
#define SMAA_AREATEX_SELECT(sample) sample.rg
#endif
#endif

#ifndef SMAA_SEARCHTEX_SELECT
#define SMAA_SEARCHTEX_SELECT(sample) sample.r
#endif

#ifndef SMAA_DECODE_VELOCITY
#define SMAA_DECODE_VELOCITY(sample) sample.rg
#endif

//-----------------------------------------------------------------------------
// Non-Configurable Defines

#define SMAA_AREATEX_MAX_DISTANCE 16
#define SMAA_AREATEX_MAX_DISTANCE_DIAG 20
#define SMAA_AREATEX_PIXEL_SIZE (1.0 / float2(160.0, 560.0))
#define SMAA_AREATEX_SUBTEX_SIZE (1.0 / 7.0)
#define SMAA_SEARCHTEX_SIZE float2(66.0, 33.0)
#define SMAA_SEARCHTEX_PACKED_SIZE float2(64.0, 16.0)
#define SMAA_CORNER_ROUNDING_NORM (float(SMAA_CORNER_ROUNDING) / 100.0)

//-----------------------------------------------------------------------------
// Porting Functions

#if defined(SMAA_HLSL_3)
#define SMAATexture2D(tex) sampler2D tex
#define SMAATexturePass2D(tex) tex
#define SMAASampleLevelZero(tex, coord) tex2Dlod(tex, float4(coord, 0.0, 0.0))
#define SMAASampleLevelZeroPoint(tex, coord) tex2Dlod(tex, float4(coord, 0.0, 0.0))
#define SMAASampleLevelZeroOffset(tex, coord, offset) tex2Dlod(tex, float4(coord + offset * SMAA_RT_METRICS.xy, 0.0, 0.0))
#define SMAASample(tex, coord) tex2D(tex, coord)
#define SMAASamplePoint(tex, coord) tex2D(tex, coord)
#define SMAASampleOffset(tex, coord, offset) tex2D(tex, coord + offset * SMAA_RT_METRICS.xy)
#define SMAA_FLATTEN [flatten]
#define SMAA_BRANCH [branch]
#endif
#if defined(SMAA_HLSL_4) || defined(SMAA_HLSL_4_1)
SamplerState LinearSampler { Filter = MIN_MAG_LINEAR_MIP_POINT; AddressU = Clamp; AddressV = Clamp; };
SamplerState PointSampler { Filter = MIN_MAG_MIP_POINT; AddressU = Clamp; AddressV = Clamp; };
#define SMAATexture2D(tex) Texture2D tex
#define SMAATexturePass2D(tex) tex
#define SMAASampleLevelZero(tex, coord) tex.SampleLevel(LinearSampler, coord, 0)
#define SMAASampleLevelZeroPoint(tex, coord) tex.SampleLevel(PointSampler, coord, 0)
#define SMAASampleLevelZeroOffset(tex, coord, offset) tex.SampleLevel(LinearSampler, coord, 0, offset)
#define SMAASample(tex, coord) tex.Sample(LinearSampler, coord)
#define SMAASamplePoint(tex, coord) tex.Sample(PointSampler, coord)
#define SMAASampleOffset(tex, coord, offset) tex.Sample(LinearSampler, coord, offset)
#define SMAA_FLATTEN [flatten]
#define SMAA_BRANCH [branch]
#define SMAATexture2DMS2(tex) Texture2DMS<float4, 2> tex
#define SMAALoad(tex, pos, sample) tex.Load(pos, sample)
#if defined(SMAA_HLSL_4_1)
#define SMAAGather(tex, coord) tex.Gather(LinearSampler, coord, 0)
#endif
#endif
#if defined(SMAA_GLSL_2_1) || defined(SMAA_GLSL_3) || defined(SMAA_GLSL_4)
#define SMAATexture2D(tex) sampler2D tex
#define SMAATexturePass2D(tex) tex
#define SMAASampleLevelZero(tex, coord) textureLod(tex, coord, 0.0)
#define SMAASampleLevelZeroPoint(tex, coord) textureLod(tex, coord, 0.0)
#define SMAASampleLevelZeroOffset(tex, coord, offset) textureLodOffset(tex, coord, 0.0, offset)
#if defined(SMAA_GLSL_2_1)
#define SMAASample(tex, coord) texture2D(tex, coord)
#define SMAASamplePoint(tex, coord) texture2D(tex, coord)
#define SMAASampleOffset(tex, coord, offset) texture2D(tex, coord + offset * SMAA_RT_METRICS.rg)
#define round(x) floor(x + 0.5)
#define textureLod(tex, coord, level) texture2D(tex, coord)
#define textureLodOffset(tex, coord, level, offset) texture2D(tex, coord + offset * SMAA_RT_METRICS.rg)
#else
#define SMAASample(tex, coord) texture(tex, coord)
#define SMAASamplePoint(tex, coord) texture(tex, coord)
#define SMAASampleOffset(tex, coord, offset) texture(tex, coord, offset)
#endif
#define SMAA_FLATTEN
#define SMAA_BRANCH
#define lerp(a, b, t) mix(a, b, t)
#define saturate(a) clamp(a, 0.0, 1.0)
#if defined(SMAA_GLSL_4)
#define mad(a, b, c) fma(a, b, c)
#define SMAAGather(tex, coord) textureGather(tex, coord)
#else
#define mad(a, b, c) (a * b + c)
#endif
#define float2 vec2
#define float3 vec3
#define float4 vec4
#define int2 ivec2
#define int3 ivec3
#define int4 ivec4
#define bool2 bvec2
#define bool3 bvec3
#define bool4 bvec4
#endif

#if !defined(SMAA_HLSL_3) && !defined(SMAA_HLSL_4) && !defined(SMAA_HLSL_4_1) && !defined(SMAA_GLSL_2_1) && !defined(SMAA_GLSL_3) && !defined(SMAA_GLSL_4) && !defined(SMAA_CUSTOM_SL)
#error you must define the shading language: SMAA_HLSL_*, SMAA_GLSL_* or SMAA_CUSTOM_SL
#endif

//-----------------------------------------------------------------------------
// Misc functions

float3 SMAAGatherNeighbours(float2 texcoord,
 float4 offset[3],
 SMAATexture2D(tex)) {
 #ifdef SMAAGather
 return SMAAGather(tex, texcoord + SMAA_RT_METRICS.xy * float2(-0.5, -0.5)).grb;
 #else
 float P = SMAASamplePoint(tex, texcoord).r;
 float Pleft = SMAASamplePoint(tex, offset[0].xy).r;
 float Ptop = SMAASamplePoint(tex, offset[0].zw).r;
 return float3(P, Pleft, Ptop);
 #endif
}

float2 SMAACalculatePredicatedThreshold(float2 texcoord,
 float4 offset[3],
 SMAATexture2D(predicationTex)) {
 float3 neighbours = SMAAGatherNeighbours(texcoord, offset, SMAATexturePass2D(predicationTex));
 float2 delta = abs(neighbours.xx - neighbours.yz);
 float2 edges = step(SMAA_PREDICATION_THRESHOLD, delta);
 return SMAA_PREDICATION_SCALE * SMAA_THRESHOLD * (1.0 - SMAA_PREDICATION_STRENGTH * edges);
}

void SMAAMovc(bool2 cond, inout float2 variable, float2 value) {
 SMAA_FLATTEN if (cond.x) variable.x = value.x;
 SMAA_FLATTEN if (cond.y) variable.y = value.y;
}

void SMAAMovc(bool4 cond, inout float4 variable, float4 value) {
 SMAAMovc(cond.xy, variable.xy, value.xy);
 SMAAMovc(cond.zw, variable.zw, value.zw);
}


#if SMAA_INCLUDE_VS
//-----------------------------------------------------------------------------
// Vertex Shaders

void SMAAEdgeDetectionVS(float2 texcoord,
 out float4 offset[3]) {
 offset[0] = mad(SMAA_RT_METRICS.xyxy, float4(-1.0, 0.0, 0.0, -1.0), texcoord.xyxy);
 offset[1] = mad(SMAA_RT_METRICS.xyxy, float4( 1.0, 0.0, 0.0, 1.0), texcoord.xyxy);
 offset[2] = mad(SMAA_RT_METRICS.xyxy, float4(-2.0, 0.0, 0.0, -2.0), texcoord.xyxy);
}

void SMAABlendingWeightCalculationVS(float2 texcoord,
 out float2 pixcoord,
 out float4 offset[3]) {
 pixcoord = texcoord * SMAA_RT_METRICS.zw;

 // We will use these offsets for the searches later on (see @PSEUDO_GATHER4):
 offset[0] = mad(SMAA_RT_METRICS.xyxy, float4(-0.25, -0.125, 1.25, -0.125), texcoord.xyxy);
 offset[1] = mad(SMAA_RT_METRICS.xyxy, float4(-0.125, -0.25, -0.125, 1.25), texcoord.xyxy);

 // And these for the searches, they indicate the ends of the loops:
 offset[2] = mad(SMAA_RT_METRICS.xxyy,
 float4(-2.0, 2.0, -2.0, 2.0) * float(SMAA_MAX_SEARCH_STEPS),
 float4(offset[0].xz, offset[1].yw));
}

void SMAANeighborhoodBlendingVS(float2 texcoord,
 out float4 offset) {
 offset = mad(SMAA_RT_METRICS.xyxy, float4( 1.0, 0.0, 0.0, 1.0), texcoord.xyxy);
}
#endif // SMAA_INCLUDE_VS

#if SMAA_INCLUDE_PS
//-----------------------------------------------------------------------------
// Edge Detection Pixel Shaders (First Pass)

float2 SMAALumaEdgeDetectionPS(float2 texcoord,
 float4 offset[3],
 SMAATexture2D(colorTex)
 #if SMAA_PREDICATION
 , SMAATexture2D(predicationTex)
 #endif
 ) {
 // Calculate the threshold:
 #if SMAA_PREDICATION
 float2 threshold = SMAACalculatePredicatedThreshold(texcoord, offset, SMAATexturePass2D(predicationTex));
 #else
 float2 threshold = float2(SMAA_THRESHOLD, SMAA_THRESHOLD);
 #endif

 // Calculate lumas:
 float3 weights = float3(0.2126, 0.7152, 0.0722);
 float L = dot(SMAASamplePoint(colorTex, texcoord).rgb, weights);

 float Lleft = dot(SMAASamplePoint(colorTex, offset[0].xy).rgb, weights);
 float Ltop = dot(SMAASamplePoint(colorTex, offset[0].zw).rgb, weights);

 // We do the usual threshold:
 float4 delta;
 delta.xy = abs(L - float2(Lleft, Ltop));
 float2 edges = step(threshold, delta.xy);

 // Then discard if there is no edge:
 if (dot(edges, float2(1.0, 1.0)) == 0.0)
 discard;

 // Calculate right and bottom deltas:
 float Lright = dot(SMAASamplePoint(colorTex, offset[1].xy).rgb, weights);
 float Lbottom = dot(SMAASamplePoint(colorTex, offset[1].zw).rgb, weights);
 delta.zw = abs(L - float2(Lright, Lbottom));

 // Calculate the maximum delta in the direct neighborhood:
 float2 maxDelta = max(delta.xy, delta.zw);

 // Calculate left-left and top-top deltas:
 float Lleftleft = dot(SMAASamplePoint(colorTex, offset[2].xy).rgb, weights);
 float Ltoptop = dot(SMAASamplePoint(colorTex, offset[2].zw).rgb, weights);
 delta.zw = abs(float2(Lleft, Ltop) - float2(Lleftleft, Ltoptop));

 // Calculate the final maximum delta:
 maxDelta = max(maxDelta.xy, delta.zw);
 float finalDelta = max(maxDelta.x, maxDelta.y);

 // Local contrast adaptation:
 edges.xy *= step(finalDelta, SMAA_LOCAL_CONTRAST_ADAPTATION_FACTOR * delta.xy);

 return edges;
}

float2 SMAAColorEdgeDetectionPS(float2 texcoord,
 float4 offset[3],
 SMAATexture2D(colorTex)
 #if SMAA_PREDICATION
 , SMAATexture2D(predicationTex)
 #endif
 ) {
 // Calculate the threshold:
 #if SMAA_PREDICATION
 float2 threshold = SMAACalculatePredicatedThreshold(texcoord, offset, predicationTex);
 #else
 float2 threshold = float2(SMAA_THRESHOLD, SMAA_THRESHOLD);
 #endif

 // Calculate color deltas:
 float4 delta;
 float3 C = SMAASamplePoint(colorTex, texcoord).rgb;

 float3 Cleft = SMAASamplePoint(colorTex, offset[0].xy).rgb;
 float3 t = abs(C - Cleft);
 delta.x = max(max(t.r, t.g), t.b);

 float3 Ctop = SMAASamplePoint(colorTex, offset[0].zw).rgb;
 t = abs(C - Ctop);
 delta.y = max(max(t.r, t.g), t.b);

 // We do the usual threshold:
 float2 edges = step(threshold, delta.xy);

 // Then discard if there is no edge:
 if (dot(edges, float2(1.0, 1.0)) == 0.0)
 discard;

 // Calculate right and bottom deltas:
 float3 Cright = SMAASamplePoint(colorTex, offset[1].xy).rgb;
 t = abs(C - Cright);
 delta.z = max(max(t.r, t.g), t.b);

 float3 Cbottom = SMAASamplePoint(colorTex, offset[1].zw).rgb;
 t = abs(C - Cbottom);
 delta.w = max(max(t.r, t.g), t.b);

 // Calculate the maximum delta in the direct neighborhood:
 float2 maxDelta = max(delta.xy, delta.zw);

 // Calculate left-left and top-top deltas:
 float3 Cleftleft = SMAASamplePoint(colorTex, offset[2].xy).rgb;
 t = abs(C - Cleftleft);
 delta.z = max(max(t.r, t.g), t.b);

 float3 Ctoptop = SMAASamplePoint(colorTex, offset[2].zw).rgb;
 t = abs(C - Ctoptop);
 delta.w = max(max(t.r, t.g), t.b);

 // Calculate the final maximum delta:
 maxDelta = max(maxDelta.xy, delta.zw);
 float finalDelta = max(maxDelta.x, maxDelta.y);

 // Local contrast adaptation:
 edges.xy *= step(finalDelta, SMAA_LOCAL_CONTRAST_ADAPTATION_FACTOR * delta.xy);

 return edges;
}
)SHADER_SOURCE";

extern const char smaa_base_shader_p3[] = R"SHADER_SOURCE(
float2 SMAADepthEdgeDetectionPS(float2 texcoord,
 float4 offset[3],
 SMAATexture2D(depthTex)) {
 float3 neighbours = SMAAGatherNeighbours(texcoord, offset, SMAATexturePass2D(depthTex));
 float2 delta = abs(neighbours.xx - float2(neighbours.y, neighbours.z));
 float2 edges = step(SMAA_DEPTH_THRESHOLD, delta);

 if (dot(edges, float2(1.0, 1.0)) == 0.0)
 discard;

 return edges;
}

//-----------------------------------------------------------------------------
// Diagonal Search Functions

#if !defined(SMAA_DISABLE_DIAG_DETECTION)

float2 SMAADecodeDiagBilinearAccess(float2 e) {
 // Bilinear access for fetching 'e' have a 0.25 offset, and we are
 // interested in the R and G edges:
 //
 // +---G---+-------+
 // | x o R x |
 // +-------+-------+
 //
 // Then, if one of these edge is enabled:
 // Red: (0.75 * X + 0.25 * 1) => 0.25 or 1.0
 // Green: (0.75 * 1 + 0.25 * X) => 0.75 or 1.0
 //
 // This function will unpack the values (mad + mul + round):
 // wolframalpha.com: round(x * abs(5 * x - 5 * 0.75)) plot 0 to 1
 e.r = e.r * abs(5.0 * e.r - 5.0 * 0.75);
 return round(e);
}

float4 SMAADecodeDiagBilinearAccess(float4 e) {
 e.rb = e.rb * abs(5.0 * e.rb - 5.0 * 0.75);
 return round(e);
}

float2 SMAASearchDiag1(SMAATexture2D(edgesTex), float2 texcoord, float2 dir, out float2 e) {
 float4 coord = float4(texcoord, -1.0, 1.0);
 float3 t = float3(SMAA_RT_METRICS.xy, 1.0);
 while (coord.z < float(SMAA_MAX_SEARCH_STEPS_DIAG - 1) &&
 coord.w > 0.9) {
 coord.xyz = mad(t, float3(dir, 1.0), coord.xyz);
 e = SMAASampleLevelZero(edgesTex, coord.xy).rg;
 coord.w = dot(e, float2(0.5, 0.5));
 }
 return coord.zw;
}

float2 SMAASearchDiag2(SMAATexture2D(edgesTex), float2 texcoord, float2 dir, out float2 e) {
 float4 coord = float4(texcoord, -1.0, 1.0);
 coord.x += 0.25 * SMAA_RT_METRICS.x; // See @SearchDiag2Optimization
 float3 t = float3(SMAA_RT_METRICS.xy, 1.0);
 while (coord.z < float(SMAA_MAX_SEARCH_STEPS_DIAG - 1) &&
 coord.w > 0.9) {
 coord.xyz = mad(t, float3(dir, 1.0), coord.xyz);

 // @SearchDiag2Optimization
 // Fetch both edges at once using bilinear filtering:
 e = SMAASampleLevelZero(edgesTex, coord.xy).rg;
 e = SMAADecodeDiagBilinearAccess(e);

 // Non-optimized version:
 // e.g = SMAASampleLevelZero(edgesTex, coord.xy).g;
 // e.r = SMAASampleLevelZeroOffset(edgesTex, coord.xy, int2(1, 0)).r;

 coord.w = dot(e, float2(0.5, 0.5));
 }
 return coord.zw;
}

float2 SMAAAreaDiag(SMAATexture2D(areaTex), float2 dist, float2 e, float offset) {
 float2 texcoord = mad(float2(SMAA_AREATEX_MAX_DISTANCE_DIAG, SMAA_AREATEX_MAX_DISTANCE_DIAG), e, dist);

 // We do a scale and bias for mapping to texel space:
 texcoord = mad(SMAA_AREATEX_PIXEL_SIZE, texcoord, 0.5 * SMAA_AREATEX_PIXEL_SIZE);

 // Diagonal areas are on the second half of the texture:
 texcoord.x += 0.5;

 // Move to proper place, according to the subpixel offset:
 texcoord.y += SMAA_AREATEX_SUBTEX_SIZE * offset;

 // Do it!
 return SMAA_AREATEX_SELECT(SMAASampleLevelZero(areaTex, texcoord));
}

float2 SMAACalculateDiagWeights(SMAATexture2D(edgesTex), SMAATexture2D(areaTex), float2 texcoord, float2 e, float4 subsampleIndices) {
 float2 weights = float2(0.0, 0.0);

 // Search for the line ends:
 float4 d;
 float2 end;
 if (e.r > 0.0) {
 d.xz = SMAASearchDiag1(SMAATexturePass2D(edgesTex), texcoord, float2(-1.0, 1.0), end);
 d.x += float(end.y > 0.9);
 } else
 d.xz = float2(0.0, 0.0);
 d.yw = SMAASearchDiag1(SMAATexturePass2D(edgesTex), texcoord, float2(1.0, -1.0), end);

 SMAA_BRANCH
 if (d.x + d.y > 2.0) { // d.x + d.y + 1 > 3
 // Fetch the crossing edges:
 float4 coords = mad(float4(-d.x + 0.25, d.x, d.y, -d.y - 0.25), SMAA_RT_METRICS.xyxy, texcoord.xyxy);
 float4 c;
 c.xy = SMAASampleLevelZeroOffset(edgesTex, coords.xy, int2(-1, 0)).rg;
 c.zw = SMAASampleLevelZeroOffset(edgesTex, coords.zw, int2( 1, 0)).rg;
 c.yxwz = SMAADecodeDiagBilinearAccess(c.xyzw);

 // Non-optimized version:
 // float4 coords = mad(float4(-d.x, d.x, d.y, -d.y), SMAA_RT_METRICS.xyxy, texcoord.xyxy);
 // float4 c;
 // c.x = SMAASampleLevelZeroOffset(edgesTex, coords.xy, int2(-1, 0)).g;
 // c.y = SMAASampleLevelZeroOffset(edgesTex, coords.xy, int2( 0, 0)).r;
 // c.z = SMAASampleLevelZeroOffset(edgesTex, coords.zw, int2( 1, 0)).g;
 // c.w = SMAASampleLevelZeroOffset(edgesTex, coords.zw, int2( 1, -1)).r;

 // Merge crossing edges at each side into a single value:
 float2 cc = mad(float2(2.0, 2.0), c.xz, c.yw);

 // Remove the crossing edge if we didn't found the end of the line:
 SMAAMovc(bool2(step(0.9, d.zw)), cc, float2(0.0, 0.0));

 // Fetch the areas for this line:
 weights += SMAAAreaDiag(SMAATexturePass2D(areaTex), d.xy, cc, subsampleIndices.z);
 }

 // Search for the line ends:
 d.xz = SMAASearchDiag2(SMAATexturePass2D(edgesTex), texcoord, float2(-1.0, -1.0), end);
 if (SMAASampleLevelZeroOffset(edgesTex, texcoord, int2(1, 0)).r > 0.0) {
 d.yw = SMAASearchDiag2(SMAATexturePass2D(edgesTex), texcoord, float2(1.0, 1.0), end);
 d.y += float(end.y > 0.9);
 } else
 d.yw = float2(0.0, 0.0);

 SMAA_BRANCH
 if (d.x + d.y > 2.0) { // d.x + d.y + 1 > 3
 // Fetch the crossing edges:
 float4 coords = mad(float4(-d.x, -d.x, d.y, d.y), SMAA_RT_METRICS.xyxy, texcoord.xyxy);
  float4 c;
 c.x = SMAASampleLevelZeroOffset(edgesTex, coords.xy, int2(-1, 0)).g;
 c.y = SMAASampleLevelZeroOffset(edgesTex, coords.xy, int2( 0, -1)).r;
 c.zw = SMAASampleLevelZeroOffset(edgesTex, coords.zw, int2( 1, 0)).gr;
 float2 cc = mad(float2(2.0, 2.0), c.xz, c.yw);

 // Remove the crossing edge if we didn't found the end of the line:
 SMAAMovc(bool2(step(0.9, d.zw)), cc, float2(0.0, 0.0));

 // Fetch the areas for this line:
 weights += SMAAAreaDiag(SMAATexturePass2D(areaTex), d.xy, cc, subsampleIndices.w).gr;
 }

 return weights;
}
#endif

//-----------------------------------------------------------------------------
// Horizontal/Vertical Search Functions

float SMAASearchLength(SMAATexture2D(searchTex), float2 e, float offset) {
 // The texture is flipped vertically, with left and right cases taking half
 // of the space horizontally:
 float2 scale = SMAA_SEARCHTEX_SIZE * float2(0.5, -1.0);
 float2 bias = SMAA_SEARCHTEX_SIZE * float2(offset, 1.0);

 // Scale and bias to access texel centers:
 scale += float2(-1.0, 1.0);
 bias += float2( 0.5, -0.5);

 // Convert from pixel coordinates to texcoords:
 // (We use SMAA_SEARCHTEX_PACKED_SIZE because the texture is cropped)
 scale *= 1.0 / SMAA_SEARCHTEX_PACKED_SIZE;
 bias *= 1.0 / SMAA_SEARCHTEX_PACKED_SIZE;

 // Lookup the search texture:
 return SMAA_SEARCHTEX_SELECT(SMAASampleLevelZero(searchTex, mad(scale, e, bias)));
}

float SMAASearchXLeft(SMAATexture2D(edgesTex), SMAATexture2D(searchTex), float2 texcoord, float end) {
 float2 e = float2(0.0, 1.0);
 while (texcoord.x > end &&
 e.g > 0.8281 && // Is there some edge not activated?
 e.r == 0.0) { // Or is there a crossing edge that breaks the line?
 e = SMAASampleLevelZero(edgesTex, texcoord).rg;
 texcoord = mad(-float2(2.0, 0.0), SMAA_RT_METRICS.xy, texcoord);
 }

 float offset = mad(-(255.0 / 127.0), SMAASearchLength(SMAATexturePass2D(searchTex), e, 0.0), 3.25);
 return mad(SMAA_RT_METRICS.x, offset, texcoord.x);

 // Non-optimized version:
 // We correct the previous (-0.25, -0.125) offset we applied:
 // texcoord.x += 0.25 * SMAA_RT_METRICS.x;

 // The searches are bias by 1, so adjust the coords accordingly:
 // texcoord.x += SMAA_RT_METRICS.x;

 // Disambiguate the length added by the last step:
 // texcoord.x += 2.0 * SMAA_RT_METRICS.x; // Undo last step
 // texcoord.x -= SMAA_RT_METRICS.x * (255.0 / 127.0) * SMAASearchLength(SMAATexturePass2D(searchTex), e, 0.0);
 // return mad(SMAA_RT_METRICS.x, offset, texcoord.x);
}

float SMAASearchXRight(SMAATexture2D(edgesTex), SMAATexture2D(searchTex), float2 texcoord, float end) {
 float2 e = float2(0.0, 1.0);
 while (texcoord.x < end &&
 e.g > 0.8281 && // Is there some edge not activated?
 e.r == 0.0) { // Or is there a crossing edge that breaks the line?
 e = SMAASampleLevelZero(edgesTex, texcoord).rg;
 texcoord = mad(float2(2.0, 0.0), SMAA_RT_METRICS.xy, texcoord);
 }
 float offset = mad(-(255.0 / 127.0), SMAASearchLength(SMAATexturePass2D(searchTex), e, 0.5), 3.25);
 return mad(-SMAA_RT_METRICS.x, offset, texcoord.x);
}

float SMAASearchYUp(SMAATexture2D(edgesTex), SMAATexture2D(searchTex), float2 texcoord, float end) {
 float2 e = float2(1.0, 0.0);
 while (texcoord.y > end &&
 e.r > 0.8281 && // Is there some edge not activated?
 e.g == 0.0) { // Or is there a crossing edge that breaks the line?
 e = SMAASampleLevelZero(edgesTex, texcoord).rg;
 texcoord = mad(-float2(0.0, 2.0), SMAA_RT_METRICS.xy, texcoord);
 }
 float offset = mad(-(255.0 / 127.0), SMAASearchLength(SMAATexturePass2D(searchTex), e.gr, 0.0), 3.25);
 return mad(SMAA_RT_METRICS.y, offset, texcoord.y);
}

float SMAASearchYDown(SMAATexture2D(edgesTex), SMAATexture2D(searchTex), float2 texcoord, float end) {
 float2 e = float2(1.0, 0.0);
 while (texcoord.y < end &&
 e.r > 0.8281 && // Is there some edge not activated?
 e.g == 0.0) { // Or is there a crossing edge that breaks the line?
 e = SMAASampleLevelZero(edgesTex, texcoord).rg;
 texcoord = mad(float2(0.0, 2.0), SMAA_RT_METRICS.xy, texcoord);
 }
 float offset = mad(-(255.0 / 127.0), SMAASearchLength(SMAATexturePass2D(searchTex), e.gr, 0.5), 3.25);
 return mad(-SMAA_RT_METRICS.y, offset, texcoord.y);
}

float2 SMAAArea(SMAATexture2D(areaTex), float2 dist, float e1, float e2, float offset) {
 // Rounding prevents precision errors of bilinear filtering:
 float2 texcoord = mad(float2(SMAA_AREATEX_MAX_DISTANCE, SMAA_AREATEX_MAX_DISTANCE), round(4.0 * float2(e1, e2)), dist);

 // We do a scale and bias for mapping to texel space:
 texcoord = mad(SMAA_AREATEX_PIXEL_SIZE, texcoord, 0.5 * SMAA_AREATEX_PIXEL_SIZE);

 // Move to proper place, according to the subpixel offset:
 texcoord.y = mad(SMAA_AREATEX_SUBTEX_SIZE, offset, texcoord.y);

 // Do it!
 return SMAA_AREATEX_SELECT(SMAASampleLevelZero(areaTex, texcoord));
}

//-----------------------------------------------------------------------------
// Corner Detection Functions

void SMAADetectHorizontalCornerPattern(SMAATexture2D(edgesTex), inout float2 weights, float4 texcoord, float2 d) {
 #if !defined(SMAA_DISABLE_CORNER_DETECTION)
 float2 leftRight = step(d.xy, d.yx);
 float2 rounding = (1.0 - SMAA_CORNER_ROUNDING_NORM) * leftRight;

 rounding /= leftRight.x + leftRight.y; // Reduce blending for pixels in the center of a line.

 float2 factor = float2(1.0, 1.0);
 factor.x -= rounding.x * SMAASampleLevelZeroOffset(edgesTex, texcoord.xy, int2(0, 1)).r;
 factor.x -= rounding.y * SMAASampleLevelZeroOffset(edgesTex, texcoord.zw, int2(1, 1)).r;
 factor.y -= rounding.x * SMAASampleLevelZeroOffset(edgesTex, texcoord.xy, int2(0, -2)).r;
 factor.y -= rounding.y * SMAASampleLevelZeroOffset(edgesTex, texcoord.zw, int2(1, -2)).r;

 weights *= saturate(factor);
 #endif
}

void SMAADetectVerticalCornerPattern(SMAATexture2D(edgesTex), inout float2 weights, float4 texcoord, float2 d) {
 #if !defined(SMAA_DISABLE_CORNER_DETECTION)
 float2 leftRight = step(d.xy, d.yx);
 float2 rounding = (1.0 - SMAA_CORNER_ROUNDING_NORM) * leftRight;

 rounding /= leftRight.x + leftRight.y;

 float2 factor = float2(1.0, 1.0);
 factor.x -= rounding.x * SMAASampleLevelZeroOffset(edgesTex, texcoord.xy, int2( 1, 0)).g;
 factor.x -= rounding.y * SMAASampleLevelZeroOffset(edgesTex, texcoord.zw, int2( 1, 1)).g;
 factor.y -= rounding.x * SMAASampleLevelZeroOffset(edgesTex, texcoord.xy, int2(-2, 0)).g;
 factor.y -= rounding.y * SMAASampleLevelZeroOffset(edgesTex, texcoord.zw, int2(-2, 1)).g;

 weights *= saturate(factor);
 #endif
}

//-----------------------------------------------------------------------------
// Blending Weight Calculation Pixel Shader (Second Pass)

float4 SMAABlendingWeightCalculationPS(float2 texcoord,
 float2 pixcoord,
 float4 offset[3],
 SMAATexture2D(edgesTex),
 SMAATexture2D(areaTex),
 SMAATexture2D(searchTex),
 float4 subsampleIndices) { // Just pass zero for SMAA 1x, see @SUBSAMPLE_INDICES.
 float4 weights = float4(0.0, 0.0, 0.0, 0.0);

 float2 e = SMAASample(edgesTex, texcoord).rg;

 SMAA_BRANCH
 if (e.g > 0.0) { // Edge at north
 #if !defined(SMAA_DISABLE_DIAG_DETECTION)
 // Diagonals have both north and west edges, so searching for them in
 // one of the boundaries is enough.
 weights.rg = SMAACalculateDiagWeights(SMAATexturePass2D(edgesTex), SMAATexturePass2D(areaTex), texcoord, e, subsampleIndices);

 // We give priority to diagonals, so if we find a diagonal we skip
 // horizontal/vertical processing.
 SMAA_BRANCH
 if (weights.r == -weights.g) { // weights.r + weights.g == 0.0
 #endif

 float2 d;

 // Find the distance to the left:
 float3 coords;
 coords.x = SMAASearchXLeft(SMAATexturePass2D(edgesTex), SMAATexturePass2D(searchTex), offset[0].xy, offset[2].x);
 coords.y = offset[1].y; // offset[1].y = texcoord.y - 0.25 * SMAA_RT_METRICS.y (@CROSSING_OFFSET)
 d.x = coords.x;

 // Now fetch the left crossing edges, two at a time using bilinear
 // filtering. Sampling at -0.25 (see @CROSSING_OFFSET) enables to
 // discern what value each edge has:
 float e1 = SMAASampleLevelZero(edgesTex, coords.xy).r;

 // Find the distance to the right:
 coords.z = SMAASearchXRight(SMAATexturePass2D(edgesTex), SMAATexturePass2D(searchTex), offset[0].zw, offset[2].y);
 d.y = coords.z;

 // We want the distances to be in pixel units (doing this here allow one
 // to better interleave arithmetic and memory accesses):
 d = abs(round(mad(SMAA_RT_METRICS.zz, d, -pixcoord.xx)));

 // SMAAArea below needs a sqrt, as the areas texture is compressed
 // quadratically:
 float2 sqrt_d = sqrt(d);
)SHADER_SOURCE";

extern const char smaa_base_shader_p4[] = R"SHADER_SOURCE(
 // Fetch the right crossing edges:
 float e2 = SMAASampleLevelZeroOffset(edgesTex, coords.zy, int2(1, 0)).r;

 // Ok, we know how this pattern looks like, now it is time for getting
 // the actual area:
 weights.rg = SMAAArea(SMAATexturePass2D(areaTex), sqrt_d, e1, e2, subsampleIndices.y);

 // Fix corners:
 coords.y = texcoord.y;
 SMAADetectHorizontalCornerPattern(SMAATexturePass2D(edgesTex), weights.rg, coords.xyzy, d);

 #if !defined(SMAA_DISABLE_DIAG_DETECTION)
 } else
 e.r = 0.0; // Skip vertical processing.
 #endif
 }

 SMAA_BRANCH
 if (e.r > 0.0) { // Edge at west
 float2 d;

 // Find the distance to the top:
 float3 coords;
 coords.y = SMAASearchYUp(SMAATexturePass2D(edgesTex), SMAATexturePass2D(searchTex), offset[1].xy, offset[2].z);
 coords.x = offset[0].x; // offset[1].x = texcoord.x - 0.25 * SMAA_RT_METRICS.x;
 d.x = coords.y;

 // Fetch the top crossing edges:
 float e1 = SMAASampleLevelZero(edgesTex, coords.xy).g;

 // Find the distance to the bottom:
 coords.z = SMAASearchYDown(SMAATexturePass2D(edgesTex), SMAATexturePass2D(searchTex), offset[1].zw, offset[2].w);
 d.y = coords.z;

 // We want the distances to be in pixel units:
 d = abs(round(mad(SMAA_RT_METRICS.ww, d, -pixcoord.yy)));

 // SMAAArea below needs a sqrt, as the areas texture is compressed
 // quadratically:
 float2 sqrt_d = sqrt(d);

 // Fetch the bottom crossing edges:
 float e2 = SMAASampleLevelZeroOffset(edgesTex, coords.xz, int2(0, 1)).g;

 // Get the area for this direction:
 weights.ba = SMAAArea(SMAATexturePass2D(areaTex), sqrt_d, e1, e2, subsampleIndices.x);

 // Fix corners:
 coords.x = texcoord.x;
 SMAADetectVerticalCornerPattern(SMAATexturePass2D(edgesTex), weights.ba, coords.xyxz, d);
 }

 return weights;
}

//-----------------------------------------------------------------------------
// Neighborhood Blending Pixel Shader (Third Pass)

float4 SMAANeighborhoodBlendingPS(float2 texcoord,
 float4 offset,
 SMAATexture2D(colorTex),
 SMAATexture2D(blendTex)
 #if SMAA_REPROJECTION
 , SMAATexture2D(velocityTex)
 #endif
 ) {
 // Fetch the blending weights for current pixel:
 float4 a;
 a.x = SMAASample(blendTex, offset.xy).a; // Right
 a.y = SMAASample(blendTex, offset.zw).g; // Top
 a.wz = SMAASample(blendTex, texcoord).xz; // Bottom / Left

 // Is there any blending weight with a value greater than 0.0?
 SMAA_BRANCH
 if (dot(a, float4(1.0, 1.0, 1.0, 1.0)) < 1e-5) {
 float4 color = SMAASampleLevelZero(colorTex, texcoord);

 #if SMAA_REPROJECTION
 float2 velocity = SMAA_DECODE_VELOCITY(SMAASampleLevelZero(velocityTex, texcoord));

 // Pack velocity into the alpha channel:
 color.a = sqrt(5.0 * length(velocity));
 #endif

 return color;
 } else {
 bool h = max(a.x, a.z) > max(a.y, a.w); // max(horizontal) > max(vertical)

 // Calculate the blending offsets:
 float4 blendingOffset = float4(0.0, a.y, 0.0, a.w);
 float2 blendingWeight = a.yw;
 SMAAMovc(bool4(h, h, h, h), blendingOffset, float4(a.x, 0.0, a.z, 0.0));
 SMAAMovc(bool2(h, h), blendingWeight, a.xz);
 blendingWeight /= dot(blendingWeight, float2(1.0, 1.0));

 // Calculate the texture coordinates:
 float4 blendingCoord = mad(blendingOffset, float4(SMAA_RT_METRICS.xy, -SMAA_RT_METRICS.xy), texcoord.xyxy);

 // We exploit bilinear filtering to mix current pixel with the chosen
 // neighbor:
 float4 color = blendingWeight.x * SMAASampleLevelZero(colorTex, blendingCoord.xy);
 color += blendingWeight.y * SMAASampleLevelZero(colorTex, blendingCoord.zw);

 #if SMAA_REPROJECTION
 // Antialias velocity for proper reprojection in a later stage:
 float2 velocity = blendingWeight.x * SMAA_DECODE_VELOCITY(SMAASampleLevelZero(velocityTex, blendingCoord.xy));
 velocity += blendingWeight.y * SMAA_DECODE_VELOCITY(SMAASampleLevelZero(velocityTex, blendingCoord.zw));

 // Pack velocity into the alpha channel:
 color.a = sqrt(5.0 * length(velocity));
 #endif

 return color;
 }
}

//-----------------------------------------------------------------------------
// Temporal Resolve Pixel Shader (Optional Pass)

float4 SMAAResolvePS(float2 texcoord,
 SMAATexture2D(currentColorTex),
 SMAATexture2D(previousColorTex)
 #if SMAA_REPROJECTION
 , SMAATexture2D(velocityTex)
 #endif
 ) {
 #if SMAA_REPROJECTION
 // Velocity is assumed to be calculated for motion blur, so we need to
 // inverse it for reprojection:
 float2 velocity = -SMAA_DECODE_VELOCITY(SMAASamplePoint(velocityTex, texcoord).rg);

 // Fetch current pixel:
 float4 current = SMAASamplePoint(currentColorTex, texcoord);

 // Reproject current coordinates and fetch previous pixel:
 float4 previous = SMAASamplePoint(previousColorTex, texcoord + velocity);

 // Attenuate the previous pixel if the velocity is different:
 float delta = abs(current.a * current.a - previous.a * previous.a) / 5.0;
 float weight = 0.5 * saturate(1.0 - sqrt(delta) * SMAA_REPROJECTION_WEIGHT_SCALE);

 // Blend the pixels according to the calculated weight:
 return lerp(current, previous, weight);
 #else
 // Just blend the pixels:
 float4 current = SMAASamplePoint(currentColorTex, texcoord);
 float4 previous = SMAASamplePoint(previousColorTex, texcoord);
 return lerp(current, previous, 0.5);
 #endif
}

//-----------------------------------------------------------------------------
// Separate Multisamples Pixel Shader (Optional Pass)

#ifdef SMAALoad
void SMAASeparatePS(float4 position,
 float2 texcoord,
 out float4 target0,
 out float4 target1,
 SMAATexture2DMS2(colorTexMS)) {
 int2 pos = int2(position.xy);
 target0 = SMAALoad(colorTexMS, pos, 0);
 target1 = SMAALoad(colorTexMS, pos, 1);
}
#endif

//-----------------------------------------------------------------------------
#endif // SMAA_INCLUDE_PS

)SHADER_SOURCE";

const char smaa_pass_1_vertex_shader[] = R"SHADER_SOURCE(

varying vec4 offset[3];
varying vec2 texcoord;

void main()
{
 texcoord = gl_MultiTexCoord0.st;
 SMAAEdgeDetectionVS( texcoord, offset);
 gl_Position = ftransform();

}

)SHADER_SOURCE";

const char smaa_pass_1_fragment_shader_luma[] = R"SHADER_SOURCE(

varying vec2 texcoord;
varying vec4 offset[3];
uniform sampler2D colorTex;

void main()
{
 gl_FragColor.xy = SMAALumaEdgeDetectionPS(texcoord, offset, colorTex).xy;
}

)SHADER_SOURCE";

const char smaa_pass_1_fragment_shader_color[] = R"SHADER_SOURCE(

varying vec2 texcoord;
varying vec4 offset[3];
uniform sampler2D colorTex;

void main()
{
 gl_FragColor.xy = SMAAColorEdgeDetectionPS(texcoord, offset, colorTex).xy;
}

)SHADER_SOURCE";

const char smaa_pass_2_vertex_shader[] = R"SHADER_SOURCE(

varying vec4 offset[3];
varying vec2 texcoord;
varying vec2 pixcoord;

void main()
{
 texcoord = gl_MultiTexCoord0.st;
 SMAABlendingWeightCalculationVS( texcoord, pixcoord, offset );
 gl_Position = ftransform();
}

)SHADER_SOURCE";

const char smaa_pass_2_fragment_shader[] = R"SHADER_SOURCE(

varying vec2 texcoord;
varying vec2 pixcoord;
varying vec4 offset[3];
uniform sampler2D edgesTex;
uniform sampler2D areaTex;
uniform sampler2D searchTex;

void main()
{
 gl_FragColor = SMAABlendingWeightCalculationPS(texcoord, pixcoord, offset, edgesTex, areaTex, searchTex, vec4(0.,0.,0.,0.));
}

)SHADER_SOURCE";

const char smaa_pass_3_vertex_shader[] = R"SHADER_SOURCE(

varying vec4 offset;
varying vec2 texcoord;

void main()
{
 texcoord = gl_MultiTexCoord0.st;
 SMAANeighborhoodBlendingVS( texcoord, offset );
 gl_Position = ftransform();
}

)SHADER_SOURCE";

const char smaa_pass_3_fragment_shader[] = R"SHADER_SOURCE(

varying vec2 texcoord;
varying vec4 offset;
uniform sampler2D colorTex;
uniform sampler2D blendTex;

void main()
{
 gl_FragColor = SMAANeighborhoodBlendingPS(texcoord, offset, colorTex, blendTex);
}

)SHADER_SOURCE";

}
}